Matrix Stack working!

2026-05-06 23:45:13 +02:00
parent 870ead1994
commit a32a2800f7
8 changed files with 210 additions and 62 deletions
@@ -0,0 +1,95 @@
+{ config, lib, ... }:
+{
+  sops.secrets = {
+    coturn_static_auth_secret = {
+      owner = "turnserver";
+      group = "turnserver";
+    };
+
+    coturn_static_auth_secret_synapse = {
+      owner = "matrix-synapse";
+      group = "matrix-synapse";
+      key = "coturn_static_auth_secret";
+    };
+  };
+
+  services = {
+    coturn = rec {
+      enable = true;
+      no-cli = true;
+      no-tcp-relay = true;
+      min-port = 49000;
+      max-port = 50000;
+      use-auth-secret = true;
+      static-auth-secret-file = config.sops.secrets.coturn_static_auth_secret.path;
+      realm = "turn.cyperpunk.de";
+      cert = "${config.security.acme.certs.${realm}.directory}/full.pem";
+      pkey = "${config.security.acme.certs.${realm}.directory}/key.pem";
+      extraConfig = ''
+        no-multicast-peers
+        denied-peer-ip=0.0.0.0-0.255.255.255
+        denied-peer-ip=10.0.0.0-10.255.255.255
+        denied-peer-ip=100.64.0.0-100.127.255.255
+        denied-peer-ip=127.0.0.0-127.255.255.255
+        denied-peer-ip=169.254.0.0-169.254.255.255
+        denied-peer-ip=172.16.0.0-172.31.255.255
+        denied-peer-ip=192.0.0.0-192.0.0.255
+        denied-peer-ip=192.0.2.0-192.0.2.255
+        denied-peer-ip=192.88.99.0-192.88.99.255
+        denied-peer-ip=192.168.0.0-192.168.255.255
+        denied-peer-ip=198.18.0.0-198.19.255.255
+        denied-peer-ip=198.51.100.0-198.51.100.255
+        denied-peer-ip=203.0.113.0-203.0.113.255
+        denied-peer-ip=240.0.0.0-255.255.255.255
+        denied-peer-ip=::1
+        denied-peer-ip=64:ff9b::-64:ff9b::ffff:ffff
+        denied-peer-ip=::ffff:0.0.0.0-::ffff:255.255.255.255
+        denied-peer-ip=100::-100::ffff:ffff:ffff:ffff
+        denied-peer-ip=2001::-2001:1ff:ffff:ffff:ffff:ffff:ffff:ffff
+        denied-peer-ip=2002::-2002:ffff:ffff:ffff:ffff:ffff:ffff:ffff
+        denied-peer-ip=fc00::-fdff:ffff:ffff:ffff:ffff:ffff:ffff:ffff
+        denied-peer-ip=fe80::-febf:ffff:ffff:ffff:ffff:ffff:ffff:ffff
+      '';
+      relay-ips = [ "178.254.8.35" ];
+    };
+
+    nginx.virtualHosts."turn.cyperpunk.de" = {
+      forceSSL = true;
+      enableACME = true;
+    };
+
+    matrix-synapse.settings = with config.services.coturn; {
+      turn_uris = [
+        "turn:${realm}:3478?transport=udp"
+        "turn:${realm}:3478?transport=tcp"
+      ];
+      turn_shared_secret_path = config.sops.secrets.coturn_static_auth_secret_synapse.path;
+      turn_user_lifetime = "1h";
+    };
+  };
+
+  security.acme.certs."turn.cyperpunk.de".group = "nginx";
+
+  users.users.turnserver.extraGroups = [ "nginx" ];
+
+  networking.firewall.interfaces.ens3 =
+    let
+      range =
+        with config.services.coturn;
+        lib.singleton {
+          from = min-port;
+          to = max-port;
+        };
+    in
+    {
+      allowedUDPPortRanges = range;
+      allowedUDPPorts = [
+        3478
+        5349
+      ];
+      allowedTCPPorts = [
+        3478
+        5349
+      ];
+    };
+}